在 Excel 中，Index函數(shù)用于返回?cái)?shù)組或單元格區(qū)域的值或值的引用，它分為數(shù)組形式和引用形式；二者的區(qū)別在于，數(shù)組形式只能引用一個(gè)連續(xù)的區(qū)域，引用形式除可以引用一個(gè)連續(xù)的區(qū)域外還可以引用多個(gè)不連續(xù)的區(qū)域，并還可以設(shè)置返回哪個(gè)區(qū)域。

Index函數(shù)常與 Match、Small、If 、 Row 等函數(shù)配合使用，其中 Index 與 Match 配合，可以實(shí)現(xiàn)返回行列對(duì)應(yīng)的多個(gè)值和查找滿足多個(gè)條件的值；Index 與 Small、If 、 Row 配合，可以實(shí)現(xiàn)一對(duì)多查找和滿足多個(gè)條件的多對(duì)多查找。

一、Excel Index函數(shù)語法

（一）數(shù)組形式

1、表達(dá)式：INDEX(Array, Row_Num, [Column_Num])

中文表達(dá)式：INDEX(數(shù)組或單元格區(qū)域, 返回行號(hào), [返回列號(hào)])

2、說明：

A、如果 Row_Num 和 Column_Num 都大于 0，Index函數(shù)返回 Row_Num 和 Column_Num 交叉處的單元格值；如果 Column_Num 大于 0，Row_Num 為 0，返回整列；如果 Row_Num 大于 0，Column_Num 為 0，返回整行。

B、如果要以數(shù)組形式返回值，行要以水平單元格區(qū)域形式輸入，列要以垂直單元格區(qū)域形式輸入；例如：{2,3,5;6,9,12}，“2,3,5;”為一行，該行分為三列。另外，必須按 Ctrl + Shift + Enter 才能返回?cái)?shù)組。

C、Row_Num 和 Column_Num 必須指向同一單元格，否則將返回引用錯(cuò)誤 #REF!；另外，在 Excel Web App 中，不能使用數(shù)組公式。

（二）引用形式

1、表達(dá)式：INDEX(Reference, Row_Num, [Column_Num], [Area_Num])

中文表達(dá)式：INDEX(對(duì)單元格區(qū)域的引用, 返回行號(hào), [返回列號(hào)], [返回區(qū)域號(hào)])

2、說明：

A、如果 Reference 為引用一個(gè)不連續(xù)的區(qū)域，必須用括號(hào)括起來；例如：(A1:C3,D4:E9)。

B、Area_Num 為可選項(xiàng)，若把它設(shè)置為 1，表示返回第一個(gè)區(qū)域；若把它設(shè)置為 2，返回第二個(gè)區(qū)域；其它的以此類推；若省略 Area_Num，則默認(rèn)返回第一個(gè)區(qū)域。

C、根據(jù)公式的需要，Index函數(shù)返回一個(gè)引用或數(shù)值；例如公式 =SUM(INDEX(D2:E8,3,2)) 中的 Index函數(shù)返回對(duì) E4 的引用；而公式=5*INDEX(D2:E8,3,2) 返回 E4 單元格中的數(shù)值，具體見下面的實(shí)例。

D、除以上幾點(diǎn)外，其它的與數(shù)組形式相同。

二、Excel Index函數(shù)數(shù)組形式的使用方法及實(shí)例

（一）返回行號(hào)與列號(hào)交叉單元格的實(shí)例

1、雙擊 D9 單元格，把公式 =INDEX(D2:E8,3,2) 復(fù)制到 D9，按回車，返回 528；操作過程步驟，如圖1所示：

圖1

2、公式中 D2:E8 為引用單元格區(qū)域，因?yàn)镮ndex函數(shù)的數(shù)組形式參數(shù) Array 既可以是數(shù)組又可以是單元格區(qū)域，第二個(gè)參數(shù) 3 為返回行號(hào)，第三個(gè)參數(shù) 2 為返回列號(hào)，由于返回行號(hào)和列號(hào)都不為 0，因此返回它們交叉單元格的值，正好是 E4；注意：返回行號(hào)與列號(hào)都從選定區(qū)域開始算起。

（二）Array為數(shù)組常量的實(shí)例

1、雙擊 A1 單元格，把公式 =INDEX({3,8,11;4,7,9},2,3) 復(fù)制到 A1，按回車，返回 9；操作過程步驟，如圖2所示：

圖2

2、公式中 {3,8,11;4,7,9} 是一個(gè)兩行三列的數(shù)組，行與行之間用半角分號(hào)（;）隔開；返回行號(hào)和列號(hào)分別為 2 和 3，也就是返回第二行第三列對(duì)應(yīng)的值，恰好是 9。

（三）返回引用錯(cuò)誤值 #REF! 的實(shí)例

1、雙擊 D9 單元格，把公式 =INDEX(D2:E8,2,3) 復(fù)制到 D9，按回車，返回引用錯(cuò)誤值 #REF!；操作過程步驟，如圖3所示：

圖3

2、公式引用區(qū)域 D2:E8 只有兩行兩列，而返回列號(hào)為 3，也就是引用了不存在的列，因此返回引用錯(cuò)誤。

三、Excel Index函數(shù)引用形式的使用方法及實(shí)例

（一）引用多個(gè)不連續(xù)區(qū)域的實(shí)例

1、雙擊 B10 單元格，把公式 =INDEX((B2:C4,D6:E9),2,1,2) 復(fù)制到 B10，按回車，返回 921；操作過程步驟，如圖4所示：

圖4

2、公式中的單元格引用區(qū)域 (B2:C4,D6:E9) 為兩個(gè)不連續(xù)的區(qū)域，因此要用括號(hào)括起來；返回區(qū)域號(hào)參數(shù) Area_Num 為 2，即返回第二個(gè)區(qū)域，返回行號(hào)和列號(hào)分別為 2 和 1，即返回 D6:E9 區(qū)域的第二行第一列，也就是 D7。

（二）省略參數(shù) Area_Num 的實(shí)例

1、雙擊 B10 單元格，把公式 =INDEX((B2:C4,D6:E9),2,1) 復(fù)制到 B10，按回車，返回 571；再次雙擊 B10，把“,D6:E9) 和一個(gè)左括 (”去掉，公式變?yōu)?=INDEX(B2:C4,2,1)，按回車，仍然返回 571；操作過程步驟，如圖5所示：

圖5

2、公式 =INDEX((B2:C4,D6:E9),2,1) 省略了參數(shù) Area_Num，默認(rèn)選擇第一個(gè)區(qū)域 B2:C4，再返回該區(qū)域第二行第一列對(duì)應(yīng)的單元格 B3；而公式 =INDEX(B2:C4,2,1) 與數(shù)組形式一樣。

（三）返回對(duì)單元格引用的實(shí)例

1、雙擊 E9 單元格，把公式 =SUM(INDEX(D2:E8,3,2)) 復(fù)制到 E9，按回車，返回 528；按住 Alt，依次按一次 M、V，打開“公式求值”窗口，單擊“求值”，公式變?yōu)?SUM($E$4)，說明Index函數(shù)返回的是對(duì) E4 的引用；操作過程步驟，如圖6所示：

圖6

2、SUM($E$4) 表示對(duì) E4 求和，$E$4 表示對(duì) E4 單元格的絕對(duì)引用。

（四）返回引用單元格的值實(shí)例

1、雙擊 E9 單元格，把公式 =5*INDEX(D2:E8,3,2) 復(fù)制到 E9，按回車，返回 2640；按住 Alt，依次按一次 M、V，打開“公式求值”窗口，按回車“求值”，公式變?yōu)?5 * 528，說明Index函數(shù)返回引用單元格的值；操作過程步驟，如圖7所示：

圖7

2、從以上兩例可知，Index函數(shù)可以根據(jù)公式的實(shí)際需求返回對(duì)單元格引用或單元格中的值。

（五）Index + Sum函數(shù)組合返回整行或整列的實(shí)例

1、把公式 =SUM(INDEX(B2:E9, 2, 0)) 復(fù)制到 E10 單元格，按回車，返回 1601；按住 Alt，依次按一次 M、V，打開“公式求值”窗口，按回車“求值”，公式變?yōu)?SUM($B$3:$E$3)，B3:E3 正是選定區(qū)域的第二行。雙擊 E10，把公式改為 =SUM(INDEX(B2:E9, 0, 3))，按回車，返回 5123，同樣方法打開“公式求值”窗口，按回車，公式變?yōu)闉?SUM($D$2:$D$9)， D2:D9 正是選定區(qū)域的第三列；操作過程步驟，如圖8所示：

圖8

2、Index函數(shù)返回整行或整列通常根據(jù)公式需要返回，僅輸入單一的Index公式通常無法返回。

四、Excel Index函數(shù)的擴(kuò)展應(yīng)用

（一）Index + Match函數(shù)組合返回行列對(duì)應(yīng)的多個(gè)值

1、假如要返回每個(gè)月各類服裝的銷量。雙擊 B12 單元格，把公式 =INDEX($A$1:$E$9, MATCH($A12,$A$1:$A$9,), MATCH(B$11,$A$1:$E$1,)) 復(fù)制到 B12，按回車，返回 567；選中 B12，把鼠標(biāo)移到 B12 右下角的單元格填充柄上，鼠標(biāo)變?yōu)槭�字架后，按住左鍵，往右拖，一直拖到 E12，則所經(jīng)過單元格都返回相應(yīng)銷量；把鼠標(biāo)移到 E12 右下角的單元格填充柄上，往下拖，則返回“3月和6月”的服裝銷量；操作過程步驟，如圖9所示：

圖9

2、公式 =INDEX($A$1:$E$9,MATCH($A12,$A$1:$A$9,),MATCH(B$11,$A$1:$E$1,)) 說明：

A、$A$1 是對(duì)行和列的絕對(duì)引用，往下拖，A1 不會(huì)變?yōu)?A2、A3、……；往右拖，A1 不會(huì)變?yōu)?B1、C1、……。$A$1:$A$9 以數(shù)組形式返回 A1 至 A9 的數(shù)據(jù)。

B、MATCH($A12,$A$1:$A$9,) 在 A1 至 A9 中查找 A12（1月），返回 A12 在 A1:A9 中的位置 2；Match函數(shù)省略了最后一個(gè)參數(shù)，默認(rèn)選擇 1，即返回小于等于查找值的最大值。

C、MATCH(B$11,$A$1:$E$1,) 在 A1 至 E1 中查找 B11（T恤），返回位置也為 2。

D、則公式變?yōu)?=INDEX($A$1:$E$9,2,2)，即在 A1:E9 中返回第二行第二列對(duì)應(yīng)的單元格 B2 中的值，即 567。

提示：如果拖出的數(shù)據(jù)相同，按 Ctrl + C 保存即可。

（二）Index + Match函數(shù)組合實(shí)現(xiàn)查找滿足多個(gè)條件的值

1、假如要查找“分類”為“男裝”且“價(jià)格為 80 的服裝名稱。雙擊 C11 單元格，把公式 =INDEX(B2:D8,MATCH(A11&B11,C2:C8&D2:D8,),1) 復(fù)制到 C11，按 Ctrl + Shift + 回車，返回“黑色T恤”；操作過程步驟，如圖10所示：

圖10

2、公式 =INDEX(B2:D8,MATCH(A11&B11,C2:C8&D2:D8,),1) 說明：

A、公式是一個(gè)數(shù)組公式，因此要按 Ctrl + Shift + 回車。

B、A11&B11 是把 A11 與 B11 連接起來，C2:C8&D2:D8 是把 C2:C8 和 D2:D8 每行對(duì)應(yīng)的值連結(jié)起來，例如 C2&D2、C3&D3。

C、則 MATCH(A11&B11,C2:C8&D2:D8,) 變?yōu)?MATCH("男裝80",{"女裝38.8";"女裝55.8";"女裝79.9";"女裝80";"女裝82";"男裝80";"男裝198"},)，接著在數(shù)組中查找“男裝80”，找到后返回它在數(shù)組中的位置 6。

D、則公式變?yōu)?=INDEX(B2:D8,6,1)，最后在 B2:D8 中返回第六行第一列交叉的單元格中的值，即 B7 中的“黑色T恤”。

（三）Index + Small + IF + Row函數(shù)組合實(shí)現(xiàn)一對(duì)多查找

1、假如要查找“銷售部”的所有員工姓名和職務(wù)。雙擊 F2 單元格，把公式 =IFERROR(INDEX(A:A,SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),ROW(A1))),"") 復(fù)制到 F2，按 Ctrl + Shift + 回車，返回“林語彤”；選中 F2，往下拖，按 Ctrl + S 保存，則返回“銷售部”的其他員工姓名；雙擊 G2，把上面的公式復(fù)制到 G2，并把公式中的 A:A 改為 C:C，按 Ctrl + Shift + 回車，返回“員工”，同樣用往下拖的方法返回其他員工職務(wù)；操作過程步驟，如圖11所示：

圖11

2、公式 =IFERROR(INDEX(A:A,SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),ROW(A1))),"") 說明：

A、B$2:B$8 以數(shù)組形式返回 B2 至 B8 中的元素，即 {"銷售部";"行政部";"銷售部";"財(cái)務(wù)部";"行政部";"銷售部";"財(cái)務(wù)部"}；$E$2 為“銷售部”；則 B$2:B$8=$E$2 變?yōu)?{"銷售部";"行政部";"銷售部";"財(cái)務(wù)部";"行政部";"銷售部";"財(cái)務(wù)部"}="銷售部"，接著，用數(shù)組中的每個(gè)元素與“銷售部”比較，如果相等返回 True，否則返回 False，最后返回 {TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE}。

B、ROW($2:$8) 以數(shù)組形式返回 2 到 8 之間的數(shù)值，即 {2;3;4;5;6;7;8}；4^8 是求 4 的 8 次方，結(jié)果為 65536（是 Excel 支持的最大值）。

C、則IF(B$2:B$8=$E$2,ROW($2:$8),4^8) 變?yōu)?IF({TRUE;FALSE;TRUE;FALSE;FALSE;TRUE;FALSE},{2;3;4;5;6;7;8},65536)，接著，從條件數(shù)組中取出第一個(gè)元素 TRUE，由于它為真，所以返回 If 第二個(gè)參數(shù)中的值，即返回?cái)?shù)組 {2;3;4;5;6;7;8} 中與條件數(shù)組對(duì)應(yīng)的元素 2；第二次從條件數(shù)組中取出第二個(gè)元素 FALSE，由于它為假，所以返回 If 第三個(gè)參數(shù)，即返回 65536；最后返回 {2;65536;4;65536;65536;7;65536}。

D、ROW(A1) 返回 A1 的行號(hào) 1；則 SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),ROW(A1)) 變?yōu)?SMALL({2;65536;4;65536;65536;7;65536},1)，接著，用 Small 在數(shù)組中查找第 1 個(gè)小值，也就是 2。

E、則公式變?yōu)?=IFERROR(INDEX(A:A,2),"")，A:A 表示引用 A 列，最后在 A 列中返回第二行的值，即返回 A2 中的值“林語彤”；IfError 用于錯(cuò)誤處理，如果 INDEX(A:A,2) 返回錯(cuò)誤，則返回空，否則返回 INDEX(A:A,2) 的返回值。

提示：如果要查找其它部門的員工，把 E2 中的“銷售部”改為其它部門按回車即可，如果沒有變化，只需按 Ctrl + S 保存。如果要把返回的值全顯示到一行，例如把“銷售部”的員工顯示到一行，只需把公式中的 ROW(A1) 改為 COLUMN(A1)，則公式變?yōu)?=IFERROR(INDEX(A:A,SMALL(IF(B$2:B$8=$E$2,ROW($2:$8),4^8),COLUMN(A1))),"")，往右拖即可。

（四）Index + Small + IF + Row函數(shù)組合實(shí)現(xiàn)多條件多對(duì)多查找

1、假如要查找所有女裝且價(jià)格為 80 的服裝名稱。雙擊 C11 單元格，把公式 =IFERROR(INDEX(B:B,SMALL(IF((C$2:C$8=$A$11)*(D$2:D$8=$B$11),ROW($2:$8),4^8),ROW(A1))),"") 復(fù)制到 C11，按 Ctrl + Shift + 回車，返回“粉紅襯衫”；用往下拖的方法返回其它符合條件的服裝名稱；操作過程步驟，如圖12所示：

圖12

2、公式與上面的 Index + Small + IF + Row函數(shù)組合公式一樣，所不同的只是 If 的條件由多個(gè)表達(dá)式組成，每個(gè)表達(dá)式之間用星號(hào)（*）連接，表示“與”的關(guān)系，即要同時(shí)滿足多個(gè)條件。