在 Excel 中，Choose函數用于從值列表中選擇索引號指定的值；它的索引號取值范圍為 1 到 254、至少有一個最多只能有 254 個。Choose函數的索引號除用數字外，還可用數組、函數和公式等；值除是數字外，還可是單元格、定義名稱和公式等。

Choose函數除獨立使用于返回某個值外，還可與 VLookUp、Match 和 Sum 等函數組合使用；例如 VlookUp + Choose 實現逆向查找，Choose + Match 實現績效或成績評定。

一、Excel Choose函數語法

1、表達示：CHOOSE(Index_Num, Value1, [Value2], ...)

中文表達示：CHOOSE(索引號, 值1, [值2], ...)

2、說明：

A、Index_Num 可以是數值、數組、對單元格的引用和公式，但數值、數組與單元格中的值、公式返回值都必須是 1 到 254 之間的數值。

如果 Index_Num 小于 1 或大于引用列表個數，Choose函數將返回值錯誤 #VALUE!。

B、如果 Index_Num 為 1，Choose函數返回 Value1；Index_Num 為 2，Choose函數返回 Value2；其它的以此類推。

C、如果 Index_Num 為小數，則只截取整數部分，小數部分被完全舍棄且不四舍五入。

D、Choose函數至少要有一個 Value，最多只能有 254 個：Value 可以是數字、單元格引用、定義的名稱、公式、函數或文本。

二、Excel Choose函數的使用方法及實例

（一）Index_Num 為數值與返回 #VALUE! 的實例

1、雙擊 A8 單元格，把公式 =CHOOSE(4,A2,A3,A4,A5) 復制到 A8，按回車，返回“香妃”；再次雙擊 A8，把 4 改變 0，按回車，返回值錯誤 #VALUE!；再雙擊 A8，把 0 改為 5，按回車，也返回值錯誤 #VALUE��；操作過程步驟，如圖1所示：

圖1

2、公式說明：

在 =CHOOSE(4,A2,A3,A4,A5) 中，4 為索引號，A2、A3、A4 和 A5 為值，公式的意思是：從 A2、A3、A4 和 A5 中選出第四值，即選出A5（香妃）；把 4 改為 0 和 5 都超出了 Index_Num 的取值范圍（Index_Num 的取值范圍為大于 0 且小于等于引用列表個數，公式中只有 4 個值，因此列表個數為 4），所以返回值錯誤 #VALUE!。

（二）Index_Num 為小數的實例

1、雙擊 E8 單元格，把公式 =CHOOSE(3.6,E2,E3,E4,E5) 復制到 E8，按回車，返回 12；；操作過程步驟，如圖2所示：

圖2

2、公式 =CHOOSE(3.6,E2,E3,E4,E5) 返回 12 恰好是 E4 中的值，說明 3.6 被取整為 3。

（三）對單元格區域的引用僅返回與公式同行單元格的實例

1、雙擊 F2 單元格，把公式 =CHOOSE(1,E2:E7) 復制到 F2，按回車，返回 10；選中 F2，把鼠標移到 F2 右下角的單元格填充柄上，鼠標變為加號后，按住左鍵，往下拖直到拖到 F4，F3 和 F4 分別返回 6 和 12；雙擊 E8 單元格，把公式 =CHOOSE(1,E2:E7) 復制到 E8，按回車，返回值錯誤 #VALUE!；操作過程步驟，如圖3所示：

圖3

2、當公式在 F2 至 F4 單元格時，都返回與它們同行的對應值，例如公式在 F2 時，返回與 F2 同行的 E2 中的值；當把公式復制到 E8 后，返回值錯誤 #VALUE!，說明對單元格區域引用時，Choose函數僅返回與公式同行單元格的值。

提示：如果要求返回引用單元格區域的所有值，需要把Choose函數放到別的函數中，例如放到Sum函數中，如 =SUM(CHOOSE(1,E2:E7)) 返回的結果為 E2 至 E7 的和。

三、Excel Choose函數的擴展使用實例

（一）VLookUp + Choose函數組合實現逆向查找（Choose 的 Index_Num 參數為數組的實例）

VLookUp + Choose函數組合的詳細解析，在《Excel VLookUp函數的使用方法，含逆向查找、一對多查找和近似匹配實例》一文中的“逆向查找”部分已經介紹，查看請點擊書名號中的文章標題。

（二）Choose + Match函數組合使用實現績效評定

1、假如要評定銷售員的銷售業績，假定銷售額在 4 萬以下為差，4 萬到 5 萬為合格，5 萬到 6 萬為良，6 萬到 7 萬為優秀，7 萬以上為優異。雙擊 D2 單元格，把公式 =CHOOSE(MATCH(C2,{0,40000,50000,60000,70000,100000}),"差","合格","良","優秀","優異") 復制到 D2按回車，返回“差”；選中 D2，把鼠標移到 D2 右下角的單元格填充柄上，鼠標變為加號后，單擊左鍵，則返回所有銷售員的業績評定；操作過程步驟，如圖4所示：

圖4

2、公式 =CHOOSE(MATCH(C2,{0,40000,50000,60000,70000,100000}),"差","合格","良","優秀","優異") 說明：

A、MATCH(C2,{0,40000,50000,60000,70000,100000}) 用于返回 C2（35000）在數組中的位置，Match函數省略了最后一個參數，默認取 1，由于數組中沒有 35000，因此返回小于等于查找值的最大值，即返回 0，0 在數組中的位置為 1，所以 Match函數返回 1。

B、則公式變為 =CHOOSE(1,"差","合格","良","優秀","優異")，接著用Choose函數返回索引號為 1 的值，該值為“差”。

提示：除 Choose + Match函數組合能實現績效評定外，LookUp函數也可以，具體請查看《Excel LookUp函數的使用方法，包含基本、多條件與近似查找及簡稱查找全稱實例》一文中的“近似查找”。

（三）用定義名稱作為Choose函數的值

1、框選 B2:B9，選擇“公式”選項卡，單擊“定義名稱”，打開“新建名稱”窗口，“名稱”保持默認的“T恤”，單擊“確定”；框選D2:D9，同樣方法為它們定義名稱“雪紡”；雙擊 F2 單元格，輸入公式 =CHOOSE(1,T恤,雪紡)，按回車，返回567，它恰好是 B2:B9 的第一個值；雙擊 F2，把 1 改為 2，按回車，返回 D2:D9 的第一個值；再次雙擊 F2，把公式改為 =SUM(CHOOSE(2,T恤,雪紡))，按回車，返回 D2:D9 之和；操作過程步驟，如圖5所示：

圖5

2、說明：

A、Choose函數的值可以是定義名稱，在公式中，定義名稱名不用加雙引號，中文名稱也不用加，例如公式中的“T恤和雪紡”都沒有加。

B、當定義名稱為對單元格區域的引用時，默認只返回與公式同行的值，從 CHOOSE 公式的第一個參數為 1 和 2 時的返回值可以說明這一點；如果要返回定義名稱包含的所有數值，需要把 Choose 放到別的函數中，如操作中把 Choose 放到Sum函數中，返回 D2:D9 之和。

提示：如果值比較多，無法一個個列到Choose函數中，也可以考慮把值定義為名稱。