跟大家分享12個職場中必備的Excel函數(shù)公式，隨著新函數(shù)的到來，很多經(jīng)典的函數(shù)組合已經(jīng)成為歷史，大家以后遇到類似的問題，直接套用即可，讓你成為同事眼中的Excel高手！

一、提取數(shù)據(jù)中的唯一值

公式：=UNIQUE(B4:B14)

這個函數(shù)是一個新函數(shù)，作用就是提取數(shù)據(jù)區(qū)域的唯一值

用法：=UNIQUE(要提取數(shù)據(jù)區(qū)域)

二、身份證號碼提取數(shù)據(jù)

提取生日：=TEXT(MID(A4,7,8),"0-00-00")

提取年齡：=DATEDIF(TEXT(MID(A4,7,8),"0-00-00"),TODAY(),"y")

提取性別：=IF(MOD(MID(A4,17,1),2)=1,"男","女")

這個已經(jīng)講過好多次了，如果想要使用這個三個公式，只需要更改【A4】為你表格中數(shù)據(jù)的具體位置即可

三、合并同類項

公式：=TEXTJOIN(",",TRUE,IF($A$4:$A$18=D8,$B$4:$B$18,""))

TEXTJOIN函數(shù)的作用是使用分隔符進行數(shù)據(jù)連接，

第一參數(shù)：","，表示將逗號用作分隔符

第二參數(shù)：TRUE，表示忽略空值

第三參數(shù)：IF($A$4:$A$18=D8,$B$4:$B$18,"")，一個數(shù)組公式，可以返回班級對應的所有姓名

四、僅僅計算篩選數(shù)據(jù)

所謂的僅計算篩選數(shù)據(jù)，其實就是不計算隱藏的數(shù)據(jù)，這個要求我們需要使用SUBTOTAL函數(shù)，這個函數(shù)一般不用輸入，我們將表格設置為超級表，勾選匯總行，再選擇自己需要的計算類型即可，匯總行的本質就是SUBTOTAL

五、找出重復數(shù)據(jù)

公式：=IF(COUNTIF($B$4:B4,B4)=1,"","是")

這個公式本質是利用countif函數(shù)來判斷的，如果數(shù)據(jù)出現(xiàn)重復，countif的結果就會大于1，最后再利用if函數(shù)輸出結果即可

六、區(qū)間判斷

公式：=IFS(B5>=90,"優(yōu)秀",B5>=80,"良好",B5>=60,"及格",B5<60,"不及格")

這類問題非常常見，計算獎金提成，判斷等級等等，最簡單的方法就是利用ifs函數(shù)

語法：=IFS(第1個條件，第1個條件正確返回的結果，第2個條件，第2個條件正確返回的結果，……)條件與結果都是成對出現(xiàn)的，最多可以設置127對

七、一對多查詢

公式：=FILTER(B4:B18,A4:A18=E4,"找不到結果")

一對多查詢，可以把它看做是一個篩選問題，而新函數(shù)FILTER就是一個篩選函數(shù)，可以輕松搞定這樣的問題

用法：FILTER（要返回結果的區(qū)域，篩選條件，篩選不到結果返回的值）

八、隔行求和

公式：=SUMPRODUCT((MOD(ROW(C4:L9),2)=1)*C4:L9)

這個函數(shù)本質是一個SUMPRODUCT函數(shù)的單條件計數(shù)，庫存的數(shù)據(jù)都在奇數(shù)行，所以我們用ROW函數(shù)獲取數(shù)據(jù)的行號，然后再用MOD求得奇數(shù)行

九、隔列求和

公式：=SUMPRODUCT((MOD(COLUMN(B5:G14),2)=1)*B5:G14)

隔列求和原理也是一樣的，現(xiàn)在【庫存】都在奇數(shù)列，所以需要使用COLUMN獲取對應的列號

十、多條件查詢

公式：=LOOKUP(1,0/((A4:A12=E4)*(B4:B12=F4)),C4:C12)

多條件查詢，我覺得使用LOOKUP函數(shù)是最簡單的，大家只需要記得函數(shù)的書寫規(guī)則即可

=LOOKUP(1,0/((條件1)*(條件2)),返回的結果列)，就是有幾個條件，就在括號里寫幾個就行了

十一、關鍵字求和

公式：=SUMIF(A4:A15,"*車間*",C4:C15)

關鍵字求和主要是利用了通配符，我將關鍵字【車間】的前后各鏈接一個星號，這樣的話只要包含車間2個字就會被統(tǒng)計

十二、關鍵字查詢

公式：=VLOOKUP("*"&D2&"*",$A$1:$B$6,2,FALSE)

這個跟關鍵字求和的原理是一樣的，也是利用通配符，將關鍵字的各鏈接一個星號達到數(shù)據(jù)查詢的目的